SECTION = "kernel"
DESCRIPTION = "Linux kernel for Embedian SMARC T335X Computer on Module devices"
LICENSE = "GPLv2"
LIC_FILES_CHKSUM = "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"

inherit kernel

require recipes-kernel/linux/linux-dtb.inc
require recipes-kernel/linux/setup-defconfig.inc

# Pull in the devicetree files into the rootfs
RDEPENDS_kernel-base += "kernel-devicetree"

# Add a run-time dependency for the PM firmware to be installed
# on the target file system.
RDEPENDS_kernel-base_append_ti33x = " am33x-cm3"
RDEPENDS_kernel-base_append_ti43x = " am33x-cm3"

# Add a run-time dependency for the VPE VPDMA firmware to be installed
# on the target file system.
RDEPENDS_kernel-base_append_dra7xx-evm = " vpe-vpdma-fw"

# Default is to package all dtb files for ti33x devices unless building
# for the specific beaglebone machine.
KERNEL_DEVICETREE_ti33x = "am335x-smarct335x.dtb am335x-evm.dtb am335x-evmsk.dtb am335x-bone.dtb am335x-boneblack.dtb"
#KERNEL_DEVICETREE_ti43x = "am43x-epos-evm.dtb am437x-gp-evm.dtb"
#KERNEL_DEVICETREE_beaglebone = "am335x-bone.dtb am335x-boneblack.dtb"
#KERNEL_DEVICETREE_omap5-evm = "omap5-uevm.dtb"
#KERNEL_DEVICETREE_dra7xx-evm = "dra7-evm.dtb"

KERNEL_EXTRA_ARGS += "LOADADDR=${UBOOT_ENTRYPOINT}"

COMPATIBLE_MACHINE = "ti33x|ti43x|omap-a15"

S = "${WORKDIR}/git"

# For 3.12y Kernel
BRANCH = "smarc-ti-linux-3.12.y"

# Corresponds to tag ti-linux-3.12.y
SRCREV = "8186c73cca4c9da970145984c6e8e3a2a1da2a63"
PV = "3.12.25"

# Append to the MACHINE_KERNEL_PR so that a new SRCREV will cause a rebuild
MACHINE_KERNEL_PR_append = "k+gitr${SRCPV}"
PR = "${MACHINE_KERNEL_PR}"

SRC_URI = "git://git@git.embedian.com/developer/smarc-ti-linux-kernel.git;protocol=ssh;branch=${BRANCH} \
        file://defconfig \
"

# Add append for AMSDK specific changes not in mainline
MACHINE_KERNEL_PR_append = "-smarc4"

require copy-defconfig.inc

KERNEL_LOCALVERSION = "-3.12.y"

KERNEL_LOCALVERSION_TAG = "-g${@d.getVar('SRCPV', True).partition('+')[2][0:7]}"

kernel_do_configure_prepend() {
    if [ ! -e ${B}/.scmversion -a ! -e ${S}/.scmversion ]
    then
        echo ${KERNEL_LOCALVERSION_TAG} > ${B}/.scmversion
        echo ${KERNEL_LOCALVERSION_TAG} > ${S}/.scmversion
    fi
}